// Written by Marco
Class SpectatorTracker extends Actor
	NotPlaceable;

var PlayerController OwnerController;
var color SpectatorColor;
var SpectatorFlame Flame;
var SpectatorUFO UFO;
var vector FlameOffset;
var transient SpecInteraction Interaction;
var Actor ViewingTarget;
var byte DisplayType;
var transient float NextFireTimer;
var float NeqFireTime,RefireRate;

var bool bClientVisible,bSetVisible,bIsVisible,bServerInit,bAllowFireLaser;

replication
{
	// Variables the server should send to the client.
	reliable if( Role==ROLE_Authority )
		SpectatorColor,bIsVisible,FlameOffset,bAllowFireLaser,DisplayType;
	reliable if( Role==ROLE_Authority && !bNetOwner )
		ViewingTarget;

	// Functions client can call.
	unreliable if( Role<ROLE_Authority )
		ServerFireLaser;

	// Functions server can call.
    unreliable if( Role==ROLE_Authority )
		ClientFirePause;
}

simulated function PostNetBeginPlay()
{
	local PlayerController PC;
	
	PC = Level.GetLocalPlayerController();
	if( PC!=None && (Owner==PC || (bNetOwner && Level.NetMode==NM_Client)) && bAllowFireLaser )
		Interaction = Class'SpecInteraction'.Static.AddTracker(PC,Self);
}
simulated function PostNetReceive()
{
	if( bClientVisible!=bIsVisible )
	{
		bClientVisible = bIsVisible;
		if( Interaction!=None )
		{
			Interaction.bActive = bIsVisible;
			Interaction.bVisible = bIsVisible;
		}
		if( !bIsVisible )
		{
			if( Flame!=None )
			{
				Flame.Kill();
				Flame = None;
			}
			if( UFO!=None )
				UFO.bHidden = true;
		}
		else
		{
			if( DisplayType==0 )
			{
				if( Flame==None )
				{
					Flame = Spawn(Class'SpectatorFlame',Self);
					Flame.SetColor(SpectatorColor);
				}
			}
			else
			{
				if( UFO==None )
				{
					UFO = Spawn(Class'SpectatorUFO',Self);
					UFO.SetColor(SpectatorColor);
				}
				UFO.bHidden = false;
			}
		}
	}
}
simulated function Destroyed()
{
	if( Flame!=None )
		Flame.Destroy();
	if( UFO!=None )
		UFO.Destroy();
	if( Interaction!=None )
	{
		Interaction.bActive = false;
		Interaction.bVisible = false;
		if( Interaction.NotifyTrack==Self )
			Interaction.NotifyTrack = None;
		Interaction = None;
	}
}
function PostBeginPlay()
{
	SpectatorColor.R = Rand(200)+55;
	SpectatorColor.G = Rand(200)+55;
	SpectatorColor.B = Rand(200)+55;
	FlameOffset.X = FRand()*40.f-20.f;
	FlameOffset.Y = FRand()*40.f-20.f;
	FlameOffset.Z = FRand()*25.f+10.f;
	bAllowFireLaser = Class'MutVisSpecs'.Default.bLasersEnabled;
	RefireRate = Class'MutVisSpecs'.Default.LaserRefireRate;
	DisplayType = Class'MutVisSpecs'.Static.GetSpectatorModel();
}
simulated function Tick( float Delta )
{
	if( Level.NetMode==NM_Client )
	{
		if( bIsVisible )
		{
			if( bNetOwner )
			{
				if( OwnerController==None )
					OwnerController = Level.GetLocalPlayerController();
				Velocity = vect(0,0,0);
				if( OwnerController.ViewTarget!=OwnerController && Monster(OwnerController.ViewTarget)==None )
					SetLocation(OwnerController.ViewTarget.Location+vect(0,0,1.25f)*OwnerController.ViewTarget.CollisionHeight+FlameOffset);
				else SetLocation(OwnerController.Location);
			}
			else if( ViewingTarget!=None )
			{
				Velocity = vect(0,0,0);
				SetLocation(ViewingTarget.Location+vect(0,0,1.25f)*ViewingTarget.CollisionHeight+FlameOffset);
			}
		}
		return;
	}
	if( OwnerController==None || OwnerController.PlayerReplicationInfo==None || OwnerController.Player==None )
	{
		Destroy();
		return;
	}
	if( !bServerInit )
	{
		bServerInit = true;
		if( Level.NetMode!=NM_DedicatedServer )
			PostNetBeginPlay();
	}
	bIsVisible = (OwnerController.Pawn==None && (OwnerController.PlayerReplicationInfo.bOnlySpectator || OwnerController.PlayerReplicationInfo.bOutOfLives));
	if( bIsVisible )
	{
		bMovable = true;
		if( OwnerController.ViewTarget!=OwnerController && Monster(OwnerController.ViewTarget)==None )
		{
			bUpdateSimulatedPosition = false;
			ViewingTarget = OwnerController.ViewTarget;
			Velocity = vect(0,0,0);
			SetLocation(OwnerController.ViewTarget.Location+vect(0,0,1.25f)*OwnerController.ViewTarget.CollisionHeight+FlameOffset);
		}
		else
		{
			if( !bUpdateSimulatedPosition )
			{
				bUpdateSimulatedPosition = true;
				ViewingTarget = None;
			}
			if( Location!=OwnerController.Location )
			{
				Velocity = (OwnerController.Location-Location)/Delta;
				SetLocation(OwnerController.Location);
			}
			else Velocity = vect(0,0,0);
		}
		bMovable = false;
	}

	if( bSetVisible!=bIsVisible )
	{
		NetUpdateTime = Level.TimeSeconds - 1;
		if( bIsVisible )
		{
			bSkipActorPropertyReplication = false;
			bHidden = false;
			NetUpdateFrequency = 20.f;
		}
		else
		{
			bSkipActorPropertyReplication = true;
			bHidden = true;
			NetUpdateFrequency = 0.5f;
		}
		bSetVisible = bIsVisible;
		if( Level.NetMode!=NM_DedicatedServer )
			PostNetReceive();
	}
}

simulated final function ClientFirePause( float Time )
{
	NextFireTimer = Level.TimeSeconds+Time;
	NeqFireTime = 200.f / Time;
}
final function ServerFireLaser()
{
	if( bIsVisible && bAllowFireLaser && NextFireTimer<Level.TimeSeconds )
	{
		ClientFirePause(RefireRate);
		NextFireTimer = Level.TimeSeconds+RefireRate;
		if( Instigator==None && KFPlayerReplicationInfo(OwnerController.PlayerReplicationInfo)!=None )
			Instigator = KFPlayerReplicationInfo(OwnerController.PlayerReplicationInfo).GetBlamePawn();
		if( Class'MutVisSpecs'.Default.ZapHealDamage>0 && Pawn(ViewingTarget)!=None && Monster(ViewingTarget)==None )
			Spawn(Class'HealProj').HealTarget = Pawn(ViewingTarget);
		else Spawn(Class'ShockProj',,,Location,OwnerController.Rotation);
	}
}
simulated final function FireLaser()
{
	ServerFireLaser();
}

defaultproperties
{
     bAllowFireLaser=True
     DrawType=DT_None
     bHidden=True
     bSkipActorPropertyReplication=True
     bUpdateSimulatedPosition=True
     Physics=PHYS_Projectile
     RemoteRole=ROLE_SimulatedProxy
     NetUpdateFrequency=0.500000
     bCollideWorld=True
     bNetNotify=True
     bBounce=True
}